# Excel VBA help - find cell content and highlight



## BWA (Jun 9, 2005)

Hi,

I want to try and create a macro that will start with the value in the first cell of one column and find it another column and highlight both itself and the other value and then move onto the next value in the cell below and repeat the same process until it reaches the end of the column.

This would result in leaving unhighlighted cells as new items as it were that did not exist before.

If anyone can help or give me a few pointers, I would be very grateful.

Cheers,

B.


----------



## Glaswegian (Sep 16, 2005)

Hi

Various ways to do this. Here's some code that I use (or modify) for a similar kind of thing. Basically, it matches the first cell in the first range against each cell in the second range and so on. If there is a match, then it turns the cell in the second range *green*. If there is no match, then it turns the cell in the first range *red*. The ranges do not have to be of equal size.

```
Sub FindDuplicates()
Dim Rng1 As Range
Dim Rng2 As Range
Dim bMatch As Boolean
Dim origRng As Range
Dim compRng As Range

On Error Resume Next
Set origRng = Application.InputBox("Choose the first range", "Range 1", Type:=8)
    If origRng Is Nothing Then Exit Sub
Set compRng = Application.InputBox("Choose the second range", "Range 2", Type:=8)
    
    For Each Rng1 In origRng
        bMatch = False
        For Each Rng2 In compRng
            If Rng1 = Rng2 Then
                bMatch = True
                Rng2.Interior.ColorIndex = 4
            End If
        Next Rng2
            If bMatch = False Then
                Rng1.Interior.ColorIndex = 3
            End If
    Next Rng1
End Sub
```
Let me know if this helps.


----------

